***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr 20, 2018                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt 1N4148W-AU A K 
.param
+vc0 = 2.742e-9		 vc1 = 6.025e-11	 vc2 = 1.072e-14
+tc1 = 1.780e-1		 tc2 = 4.052e-2		
d1 A K diode
g1 K A value = {(vc0+vc1*v(K,A)+vc2*v(K,A)*v(K,A))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
.model diode d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 9.035e-9		   n = 2.062		  rs = 1.150		 ikf = 8
+ibv = 0.1e-3		 nbv = 1		  bv = 110
***** capacitance parameter *****
+cjo = 7.261e-13	   m = 2.164e-2		  vj = 1.204
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.158		 xti = 3
+trs1 = 7.231e-4	trs2 = 4.025e-6		tikf = -1e-4		
.ends 1N4148W-AU
*$