***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jun 13, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5560A-AU     drain  gate  source
Lg     gate   g1   2.2n
Ld     drain  d1   100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     1.459
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=285.7  VTO=2.75  LEVEL=3  VMAX=1.2e5  ETA=0  gamma=1.2 nfs=1.01495e+12)
Rd     d1    d2    1.3m TC=5.5m,14u
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=66     TBV1=3.67e-4   TBV2=-2.3e-7  CJO=3.71e-09  M=1.600  VJ=3.895e+1)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=1.131e-17  N=6.097e-1  RS=0.04u  EG=1.160  TT=30n  ikf=2.647e-2)
Rdiode  d1  21    1.081e-3 TC=2.2m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   1.479e-9
.MODEL     DGD    D(M=1.513   CJO=1.479e-9   VJ=7.787)
Rpar      b    d2   1Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    3.9825e-9
.ENDS
*$