***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Sep 12, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PSMQC060N06LS1     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     1.234
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=182.2  VTO=2.68  LEVEL=3  VMAX=5e4  ETA=0.006  nfs=6.97e11  gamma=0.73)
Rd     d1    d2    3.71e-3    TC=4.75e-3,1.0e-5
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=66  TBV1=4.355e-4 TBV2=-6.905e-7  CJO=1.732e-9  M=0.6339  VJ=10)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=2.839e-12  N=1.006  RS=4e-8  EG=1.16  TT=20n IKF=4.234)
Rdiode  d1  21    1.685e-3 TC=2.8e-3
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   6.844e-10
.MODEL     DGD    D(cjo=6.555e-10   M=1.446   VJ=6.247)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    2.016e-9
.ENDS PSMQC060N06LS1
*$