***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr 29, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ4576AP-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     1.43
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=67  VTO=2.59  LEVEL=3  VMAX=1e5  ETA=0.006  nfs=8.5e9  gamma=1.32 )
Rd     d1    d2    11.75m TC=6.19m,1.71e-5
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=110  TBV1=4.855e-4  TBV2=-5.2e-7 CJO=8.86e-10  M=1.96  VJ=58.186)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=1.67e-14  N=0.849  RS=12.04u  EG=1.13  TT=20n ikf=0.568)
Rdiode  d1  21   2.96e-3 TC=2.05m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   5.519e-10
.MODEL     DGD    D(M=1.675   CJO=5.398e-10   VJ=8.215)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    6.053e-10
.ENDS
*$