***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jan 08, 2025                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJC138K     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     112.06
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=2.02  VTO=1.5  LEVEL=3  VMAX=5e4  ETA=0.006  nfs=1.000e10  gamma=0.9)
Rd     d1    d2    1.050   TC=6.5m,21u
Dbd     s2    d2    Dbt
.MODEL   Dbt   D(BV=55  TBV1=1.155e-3 TBV2=5.055e-8  CJO=4.737e-12  M=3.345e-1  VJ=3.905e-1)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=6.795e-8  N=2.040  RS=4e-8  EG=1.000  TT=20n IKF=2.306 ;tikf=7.5e-4)
Rdiode  d1  21    9.823e-2 TC=-0.5m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   1.124e-11
.MODEL     DGD    D(cjo=1.124e-11   M=4.048e-1   VJ=3.905e-1)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    1.673e-11
.ENDS PJC138K
*$