***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Nov 10, 2017                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt RB751S40 A K 
.param
+vc0 = 9.1e-4
+vc1 = 6.1e-5
+vc2 = 3.5e-5
+tc1 = 8.075e-2
+tc2 = 4.073e-2
gdiode K A value={(vc0+vc1*v(K,A)+vc2*v(K,A)*v(K,A))*1e-6*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d1 A K sbd
.model sbd d
***** flag parameter ***
+level = 3                     
***** dc model parameter ***
+ibv = 0.5e-3                   
+ is = 6.595e-9
+  n = 1.081
+ rs = 2.514
+ikf = 1.055e-2
+ bv = 44
***** capacitance parameter ***
+cjo = 3.589e-12
+ vj = 3.464e-1                      
+  m = 3.589e-1
+ fc = 0.5
***** temperature coefficient ***
+tnom = 25                     
+  eg = 0.650
+ xti = 3.5
+trs1 = 2.878e-3
+trs2 = -3.902e-5
+tikf = -5.832e-3
.ends RB751S40
*$